#79417 - scorpion_glitch - Thu Apr 13, 2006 3:46 pm
I've tried .rm to .mpg to .dpg but that din't work.
I've tried .rm to .avi but it didn't get ten minuets into it before it reached 2GB
So how do I get .rm files converted to .dpg (recomendations)
I all so have an .wmv that I converted to .dpg but it all so didn't work.
no sound and no video. I've seen this problem twice on forums but have not gotten a real answer, or any answer for that matter.
Please help.
And can you be overly detailed because i have changed settings on my dpgenc so I have no "defaults"
#79430 - tepples - Thu Apr 13, 2006 5:41 pm
| scorpion_glitch wrote: |
I've tried .rm to .mpg to .dpg but that din't work.
I've tried .rm to .avi but it didn't get ten minuets into it before it reached 2GB |
Did you try .rm to .avi with Huffyuv codec and a reduction in video frame rate and video size?
_________________
-- Where is he?
-- Who?
-- You know, the human.
-- I think he moved to Tilwick.
#79432 - LS5 - Thu Apr 13, 2006 6:03 pm
I've created the following batchfile for personal use, mainly to circumvent the terrible internal resizer of mencoder and almost just as bad resampler of ffmpeg (both are used by dpgenc), but it has a nice 'side-effect' of allowing pretty much all video files to be converted.
| Quote: |
::Hide DOS commands.
@echo off
::Filename of media file to convert. Full path needed when not in same directory as batch file.
set source=D:\Test.avi
::Frames per second. 16 and 12 seem to be a good value for respectively WS and FS videos.
set fps=12
::Filename of external subtitle file. Full path needed when not in same directory as batch file. Requires VSFilter.dll to be in Avisynth plugins directory. Leave blank to not include external subtitles.
set sub=
::Resizing method. From smooth to sharp: Bilinear, Bicubic, Lanczos, Lanczos4. A sharp resizing method requires a slightly higher bitrate to achieve the same quality as a smooth resizing method. When in doubt, use Bicubic. Leave blank to let mencoder handle video resizing (not recommended).
set resize=Bicubic
::Video width. Must be dividable by 16. Use 256 to completely utilize the DS screen.
set w=256
::Video height. Must be dividable by 16. 144 and 192 are correct values for respectively WS and FS videos when a width of 256 is used.
set h=192
::Resample method. SSRC offers the best quality, but can produce garbled sound in rare instances, in which case ResampleAudio should be used. Leave blank to let ffmpeg handle audio resampling (not recommended).
set resample=SSRC
::FourCC code of codec used for temporary AVI file. Use null for no compression. Use of lossless codec recommended to keep size of temporary video file down.
set fourcc=null
::DPG tools directory.
set dpg=%programfiles%\DPG tools
::DPG tools language code.
set language=.ENG
::Audio bitrate. Must be one of the following: 16, 32, 48, 64, 80, 96, 112, 128, 144, 160. A higher bitrate will result in higher quality at the expense of a bigger filesize.
set audiobitrate=160
::Video bitrate. Must be one of the following: 64, 80, 96, 112, 128, 144, 160, 176, 192, 208, 224, 240, 256. A higher bitrate will result in higher quality at the expense of a bigger filesize.
set videobitrate=224
::Abort if media file does not exist.
if not exist "%source%" exit
::Add media file to AVS script.
echo DirectShowSource("%source%",fps=%fps%,convertfps=true) > "%source%.avs"
::Add subtitle file to AVS script if entered filename exists.
if exist "%sub%" echo TextSub("%sub%") >> "%source%.avs"
::Add video resizing code to AVS script if method is defined.
if not "%resize%"=="" echo %resize%Resize(%w%,%h%) >> "%source%.avs"
::Add audio resampling code to AVS script if method is defined.
if not "%resample%"=="" echo %resample%(32000) >> "%source%.avs"
::Create WAV file.
avs2wav "%source%.avs"
::Rename WAV file to be recognized by dpgenc.
move /y "%source%.avs.wav" "%source%.wav"
::Create AVI file.
avs2avi "%source%.avs" -w -c %fourcc%
::Remove AVS file.
del "%source%.avs"
::Calculate bitrate to insert into mencoder.
set /a videobitrate2=%videobitrate%/%fps%*24
::Backup dpgenc.ini.
move /y "%dpg%\dpgenc.ini" "%dpg%\dpgenc.ini.bak"
::Generate dpgenc.ini.
echo [global] > "%dpg%\dpgenc.ini"
echo Language=%language% >> "%dpg%\dpgenc.ini"
echo [option] >> "%dpg%\dpgenc.ini"
echo SndKBPS=%audiobitrate% >> "%dpg%\dpgenc.ini"
echo SndGetMode=4 >> "%dpg%\dpgenc.ini"
echo SourceFilename=%source%.avi >> "%dpg%\dpgenc.ini"
echo [reencoption] >> "%dpg%\dpgenc.ini"
echo Width=%w% >> "%dpg%\dpgenc.ini"
echo KBPS=%videobitrate% >> "%dpg%\dpgenc.ini"
echo FPS=%fps% >> "%dpg%\dpgenc.ini"
echo CmdLine=-noautosub -nosound -frames %%0:d -demuxer rawvideo -rawvideo fps=24:w=%w%:h=%h%:format=bgr24:size=%%3:d -ovc lavc -lavcopts vcodec=mpeg1video:vbitrate=%videobitrate2% >> "%dpg%\dpgenc.ini"
::Run dpgenc.
"%dpg%\dpgenc"
::Restore dpgenc.ini backup.
move /Y "%dpg%\dpgenc.ini.bak" "%dpg%\dpgenc.ini"
::Remove temporary WAV file.
del "%source%.wav"
::Remove temporary AVI file.
del "%source%.avi" |
Note that it requires the latest version of Avisynth (http://www.avisynth.org/) installed and AVS2WAV (http://webjory.tripod.com/avisynth/avs2wav.htm) and AVS2AVI (http://www.avs2avi.org/) must be in the directory of the batch file. Also, you have to edit the second subsection of the batch file for every different video file, and it will create enormous temporary files (think 1+ GB for every half hour of video). Might seem like a lot of work at first, but the quality is worth it for me.
Last edited by LS5 on Thu Apr 13, 2006 6:04 pm; edited 1 time in total
#79433 - mntorankusu - Thu Apr 13, 2006 6:04 pm
Install Real Alternative and you should be able to use DPGenc on the RM files directly. It worked for me.
Edit: http://www.free-codecs.com/download/Real_Alternative.htm
#79539 - scorpion_glitch - Fri Apr 14, 2006 5:36 am
Ok I converted it with real alternative as a plugin. It appeared to work but when I try to run it moonshell freezes. In fact no .dpg work on my ds can anyone help me please. I have:
DS blue screen
Flash me latest
moonshell latest 1.11, 1.6 I think
SuperCard SD
256MB SD
#79974 - scorpion_glitch - Mon Apr 17, 2006 9:29 pm
I still can't get dpg's to work my DS freezes only for dpg's
DS blue screen
Flash me latest
moonshell latest 1.11, 1.6 I think
SuperCard SD
SanDisk 256MB SD
Lexar 512MB SD